[Magelord648]

There's nothing in the start script so it must be an item.

EDIT: This explains it. It's the script on the totem.

Begin totemScript

;THIS SCRIPT CREATES A 10% CHANCE OF BEARS ATTACKING THE PLAYER IN HIS SLEEP WHILE IN THE PC'S POSSESSION

short bearchance
short beardist
short placebear
short temp

if ( GetJournalIndex BM_Ceremony1 == 20 )
	if ( player->GetItemCount misc_BM_ClawFang_UNIQUE > 0 )
		Journal BM_Ceremony1 30
	endif
endif

if ( player->GetItemCount misc_BM_ClawFang_UNIQUE == 0 ) ;DOES PC HAVE TOTEM
	return
endif

if ( GetPCSleep != 1 ) ;IS PC ASLEEP, ALSO RESET VARIABLE
	return
	set beardist to 0
	set placebear to 0
endif

set bearchance to Random100 ;MAKE VARIABLE A RANDOM NUMBER 0-100

if ( bearchance > 10 ) ;ONLY 10% CHANCE OF ATTACK
	return
endif

;CHECK PLAYER LEVEL, PLACE BEARS, MAKE BEARS ATTACK

if ( player->GetLevel >= 30 )
	set placebear to 3
elseif ( player->GetLevel >= 20 )
	set placebear to 2
elseif ( player->GetLevel < 20 )
	set placebear to 1
endif

set temp to placebear
set beardist to ( beardist + 128 )

while ( temp != 0 )
	PlaceAtPC BM_bear_black_Claw_UNIQ 1 beardist 1
	set temp to ( temp - 1 )
endwhile

WakeUpPC
MessageBox "You are awakened by the sounds of bears around you."


End totemScript

It doesn't specify a location so you can be attacked anywhere.